TOPIC:

unit Unit1;
//Obviously coming from here:
//http://forum.lazarus.freepascal.org/index.php?topic=24109.0
//It can't work directly ;)

{$mode objfpc}{$H+}

interface

uses
  Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, StdCtrls,
  ExtCtrls, math;


type
  //Definition of the class
  TLorenz = class
    a,
    b,
    c : string;
    v : integer;
  end;

type
  { TForm1 }
  TForm1 = class(TForm)
    Button1  : TButton;
    Label1   : TLabel;
    Label2   : TLabel;
    ListBox1 : TListBox;
    ListBox2 : TListBox;
    procedure Button1Click(Sender: TObject);
  private
    { private declarations }
    procedure RunMe;
  public
    { public declarations }
  end;

var
  Form1: TForm1;

//The sorting function must be declared out of TForm1
function SortLorenzByValue(Item1, Item2 : Pointer) : Longint;

implementation

{$R *.lfm}

//Definition of a Compare function
//Must not belong to an object (not a method of TForm1 for example)
function SortLorenzByValue(Item1, Item2 : Pointer) : longint;
begin
  Result :=
    CompareValue( TLorenz(Item1).v    //You need to do explicit conversion
                , TLorenz(Item2).v ); //of types before to compare them
                                      //Otherwise you will compare the pointers ^^
// See http://www.delphibasics.co.uk/RTL.asp?Name=CompareValue
// LessThanValue   -1
// EqualsValue      0
// GreaterThanValue 1
end;

{ TForm1 }
procedure TForm1.RunMe;
var i       : integer;  //Need to declare the counter
    aList   : TList;    //The list, contains (untyped) pointers only
    aLorenz : TLorenz;  //An instance of TLorenz
begin
  //Intantiate the list, only pointers
  aList := TList.Create;

  try
    {%REGION 'Creation of 10 instances'}
    for i := 0 to 9 do
    begin
      aLorenz   := TLorenz.Create; //Create an instance
      aLorenz.a := 'Hello World';  //Set a but b and c not initialized :P
      aLorenz.v := Random(1000);   //Random value

      aList.Add( aLorenz );        //Add the instance to the List
    end;
    {%ENDREGION}

    {%REGION 'Clearing the ListBoxes'}
    ListBox1.Items.Clear;      //Clear the ListBox "Before"
    Listbox1.Sorted := False;  //I didn't cheat, the ListBox is not sorted by default)

    ListBox2.Items.Clear;      //Clear the ListBox "After"
    Listbox2.Sorted := False;  //I didn't cheat, the ListBox is not sorted by default)
    {%ENDREGION}

    {%REGION 'Population of the ListBox "Before" with unsorted values'}
    for i := 0 to aList.Count-1 do //Iterate
      ListBox1.Items.Add( //Add in the ListBox an element
        IntToStr(         //... made of the conversion from int to string
          TLorenz(        //... made of the conversion from (untyped) pointer to Tlorenz
            aList[i]      //... of list element of index [i]
          ).v             //... from which I'm considering the value v
        )
      ); //It was painful, but it is finished :P
    {%ENDREGION}

    //Sorting the list, calling the compare procedure
    aList.Sort( @SortLorenzByValue );

    {%REGION 'Population of the ListBox "After" now with sorted values'}
    for i := 0 to aList.Count-1 do //Iterate
      ListBox2.Items.Add( //Add in the ListBox an element
        IntToStr(         //... made of the conversion from int to string
          TLorenz(        //... made of the conversion from (untyped) pointer to Tlorenz
            aList[i]      //... of list element of index [i]
          ).v             //... from which I'm considering the value v
        )
      ); //It was painful, but it is finished :P
    {%ENDREGION}

   finally
    //TList.Free deletes the references but does not free it
    //In fact you need to iterate through the list to delete each instance
    for i := 0 to aList.Count-1 do
      TLorenz(aList[i]).Free;

    //Free the list itself
    aList.Free;
   end;

end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  RunMe;
end;

end.